initial commit

.gitignore

@@ -0,0 +1 @@
+result

flake.lock

@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1782233679,
+        "narHash": "sha256-QyuGP5+QOtmXpy4i2X4DhBVBaySBdDKQEhqKcphcp34=",
+        "owner": "nixos",
+        "repo": "nixpkgs",
+        "rev": "667d5cf1c59585031d743c78b394b0a647537c35",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nixos",
+        "ref": "nixos-26.05",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,14 @@
+{
+  description = "Oryxis - A modern SSH client built entirely in Rust. Fast, encrypted, native.";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
+  };
+
+  outputs = { self, nixpkgs }: {
+    packages.x86_64-linux.oryxis =
+      nixpkgs.legacyPackages.x86_64-linux.callPackage ./package.nix {};
+
+    packages.x86_64-linux.default = self.packages.x86_64-linux.oryxis;
+  };
+}

package.nix

@@ -0,0 +1,64 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, pkg-config
+, makeWrapper
+, openssl
+, gtk3
+, wayland
+, libxkbcommon
+, libGL
+, vulkan-loader
+, libx11
+, libxcursor
+, libxrandr
+, libxi
+}:
+
+let
+  runtimeLibs = [
+    wayland
+    libxkbcommon
+    libGL
+    vulkan-loader
+    libx11
+    libxcursor
+    libxrandr
+    libxi
+  ];
+in
+rustPlatform.buildRustPackage rec {
+  pname = "oryxis";
+  version = "0.8.2";
+
+  src = fetchFromGitHub {
+    owner = "wilsonglasser";
+    repo = "oryxis";
+    rev = "v${version}";
+    hash = "sha256-lc8tUUiH6DzGgKQHFPA7WkuCaOGQTSzddUeAwyazK+c=";
+  };
+
+  cargoHash = "sha256-6PWrHvXU9r9b3/4LZtYgHmg+5qBz6IDriLf8Kc5xhLE=";
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+  ];
+
+  buildInputs = [
+    openssl
+    gtk3
+    wayland
+    libxkbcommon
+  ];
+
+  # Use the system openssl (from buildInputs) rather than vendoring it.
+  OPENSSL_NO_VENDOR = 1;
+
+  postFixup = ''
+    for bin in $out/bin/*; do
+      wrapProgram "$bin" \
+        --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath runtimeLibs}"
+    done
+  '';
+}